feat: add navidrome module and enable on shan

flake.nix

@@ -52,6 +52,7 @@
       perSystem =
         { pkgs, ... }:
         {
+          formatter = pkgs.nixfmt-rfc-style;
           devShells.default = pkgs.mkShell {
             buildInputs = with pkgs; [
               pre-commit

hosts/brontes/configuration.nix

@@ -21,7 +21,6 @@
   hardware.bluetooth.powerOnBoot = true;
 
   services.blueman.enable = true;
-  services.flatpak.enable = true;
 
   #: Power Consumption {{{
   services.logind = {

hosts/shan/configuration.nix

@@ -14,11 +14,25 @@ in
     ./disk-config.nix
     ../../modules/nix
   ];
+
   boot.loader.grub = {
     efiSupport = true;
     efiInstallAsRemovable = true;
   };
 
+  modules.server.navidrome = {
+    enable = false;
+    library = {
+      path = "/mnt/music";
+      type = "nfs";
+      source = {
+        ip = "192.168.178.21";
+        path = "/mnt/Fort/data/music";
+      };
+    };
+    settings = { };
+  };
+
   services.openssh.enable = true;
 
   environment.systemPackages = map lib.lowPrio [

options/default.nix

@@ -3,5 +3,6 @@
     ./media.nix
     ./system.nix
     ./pulseview.nix
+    ./navidrome.nix
   ];
 }

options/navidrome.nix

@@ -0,0 +1,66 @@
+{
+  lib,
+  config,
+  options,
+  ...
+}:
+let
+  inherit (lib) mkIf mkOption mkEnableOption;
+  inherit (lib.types)
+    enum
+    listOf
+    submodule
+    nonEmptyStr
+    ;
+  cfg = config.modules.server.navidrome;
+in
+{
+  options.modules.server.navidrome = {
+    enable = mkEnableOption "Navidrome";
+
+    library = {
+      type = mkOption {
+        type = enum [
+          "local"
+          "nfs"
+        ];
+        default = "local";
+      };
+      path = mkOption { type = nonEmptyStr; };
+      source = mkOption {
+        default = { };
+        type = submodule {
+          options = {
+            ip = mkOption { type = nonEmptyStr; };
+            path = mkOption { type = nonEmptyStr; };
+            options = mkOption {
+              default = [
+                "x-systemd.automount"
+                "noauto"
+                "ro"
+              ];
+              type = listOf nonEmptyStr;
+            };
+          };
+        };
+      };
+    };
+    settings = options.services.navidrome.settings;
+  };
+
+  config = mkIf cfg.enable {
+    fileSystems.${cfg.library.path} = mkIf (cfg.library.type == "nfs") {
+      device = "${cfg.library.source.ip}:${cfg.library.source.path}";
+      fsType = "nfs";
+      options = cfg.library.source.options;
+    };
+
+    services.navidrome = {
+      enable = true;
+      openFirewall = true;
+      settings = {
+        MusicFolder = cfg.library.path;
+      } // cfg.settings;
+    };
+  };
+}