{
  lib,
  inputs,
  self,
  ...
}:
{

  # Verify the existence of a binary inside of a derivation.
  # Returns the path to the binary or throws.
  checkPath =
    pkg: bin:
    let
      abs = lib.getExe' pkg bin;
    in
    if builtins.pathExists abs then abs else throw "${abs} does not exist.";

  mkSystem =
    {
      withSystem,
      hostname,
      extraModules ? [ ],
      system,
    }:
    withSystem system (
      { inputs', self', ... }:
      lib.nixosSystem {
        inherit system;
        modules = [
          "${self}/hosts/${hostname}/configuration.nix"
          "${self}/options"
          "${self}/modules/commons"
          { networking.hostName = hostname; }
        ] ++ extraModules;
        specialArgs = {
          inherit inputs inputs';
          inherit self self';
          pubkeys = import ../../options/keys.nix { inherit lib; };
          username = "ny";
        };
      }
    );

  validatePath =
    s: if (builtins.pathExists s) then (builtins.baseNameOf s) else throw "${s} does not exist";
}