{
  lib,
  rustPlatform,
  fetchFromGitHub,
  curl,
  pkg-config,
  wrapGAppsHook,
  atk,
  bzip2,
  cairo,
  gdk-pixbuf,
  glib,
  gtk3,
  libusb,
  libxkbcommon,
  openssl,
  pango,
  udev,
  vulkan-loader,
  zlib,
  stdenv,
  darwin,
  wayland,
  autoPatchelfHook,
  makeWrapper,
  libGL,
}:

rustPlatform.buildRustPackage rec {
  pname = "pineflash";
  version = "82605e4eeb48d25e59361ea42bcb01f02588b6aa";

  src = fetchFromGitHub {
    owner = "Nydragon";
    repo = "PineFlash";
    rev = version;
    hash = "sha256-s/yUB0mqXDD+InlWW/cDuk63K/mNZp158CD99RmHZrY=";
    fetchSubmodules = true;
  };

  cargoHash = "sha256-DuxKkC3+3Ynct0TAUNB8/O8b1/Cj4FoeUilxhYnSdwk=";

  nativeBuildInputs = [
    curl
    pkg-config
    wrapGAppsHook
    autoPatchelfHook
    makeWrapper
  ];

  buildInputs =
    [
      atk
      bzip2
      cairo
      curl
      gdk-pixbuf
      glib
      gtk3
      libusb
      libxkbcommon
      openssl
      pango
      udev
      vulkan-loader
      zlib
    ]
    ++ lib.optionals stdenv.isDarwin [
      darwin.apple_sdk.frameworks.AppKit
      darwin.apple_sdk.frameworks.CoreFoundation
      darwin.apple_sdk.frameworks.CoreGraphics
      darwin.apple_sdk.frameworks.CoreServices
      darwin.apple_sdk.frameworks.Foundation
      darwin.apple_sdk.frameworks.Metal
      darwin.apple_sdk.frameworks.QuartzCore
      darwin.apple_sdk.frameworks.Security
      darwin.apple_sdk.frameworks.SystemConfiguration
    ]
    ++ lib.optionals stdenv.isLinux [
      wayland
    ];

  patches = [
    # remove when merged: https://github.com/Spagett1/pineflash/pull/86
    ./fix-crash.patch
  ];

  preFixup = ''
    wrapProgram $out/bin/pineflash \
        --prefix LD_LIBRARY_PATH : ${
          lib.makeLibraryPath [
            wayland
            libGL
            libxkbcommon
          ]
        } \
        --set RUST_SRC_PATH "${rustPlatform.rustLibSrc}"
  '';

  meta = {
    description = "A tool to flash ironos to the pinecil soldering iron and possibly other pine64 devices in the future";
    homepage = "https://github.com/Spagett1/PineFlash";
    license = lib.licenses.gpl3Only;
    maintainers = with lib.maintainers; [ ];
    mainProgram = "pineflash";
  };
}